Mirc İrc Chanserv Yetki Ekleme Paneli

Sohbet Girişi

   
   
Şifreniz yoksa boş bırakabilirsiniz.
Mirc İrc Chanserv Yetki Ekleme Paneli

 

Buradasınız: Mirc – Remote – Mirc İrc Chanserv Yetki Ekleme Paneli


Ekleme: Mircinizde Alt+R tuşuna basın sol üstte dosya => yeni ekle seçin. Kodları yapıştırın.

Kullanımı mircinizde sağ tuşa tıklayıp chanserv yetki paneline tıklayın.

dialog ch.access {
  title "Chanserv Access Paneli"
  size -1 -1 251 142
  option dbu
  box "Kanali Seç", 1, 2 0 65 111
  combo 2, 4 9 60 50, size drop
  combo 3, 4 24 60 50, size
  edit "Kaç LeveLs ?", 4, 4 73 60 10, center
  button "Ekle", 5, 14 89 37 12
  box "Alt Kısımdakiler Access Seviyelerini ve Nickleri Gösterir.", 6, 67 0 179 111
  combo 7, 70 9 173 75, size
  button "Kaldir", 8, 73 86 37 12
  edit "Access Level", 9, 154 86 50 11, center
  button "Düzenle", 10, 205 85 37 12
  button "Tamam Kapat.", 11, 190 116 54 12, ok
  text "  Kullanimi : İlk önce Kanali Seçiyorsunuz.  Sonra bi altina Nicki yaziyorsunuz. Kaç Levels yazan yerede Seviyesini yazip Ekle diyorsunuz. ßy RosicRucian", 12, 12 116 150 22
}

alias access { dialog -m ch.access ch.access }

Menu Channel {
  Chanserv Yetki Paneli:access
}

on ^*:NOTICE:*:?:{
  if ($dialog(ch.access)) && ($nick == Chanserv) {
    if (Access list for isin $1-) { haltdef }
    if (must be non-zero isin $1-) { haltdef | echo -a  4Error: Level must be a number and non-zero }
    if ($2 = VOP) || ($2 = HOP) || ($2 = AOP) || ($2 = SOP) {
      if (%halt.x = on) { halt }
      haltdef 
      did -a ch.access 7 Chan must have xOp turned off 
      set -u3 %halt.x on 
    }
    if ($1 isnum) && ($2 isnum) { haltdef | did -a ch.access 7 $3 - Access Level $2 } 
    if (Num isin $1-) { haltdef }
    if (End isin $1-) { haltdef }
    if (Access Denied isin $1-) { haltdef | did -a ch.access 7 Access Denied }
    if (added to isin $1-) { haltdef }
    if (deleted from isin $1-) { haltdef }
    if (changed isin $1-) { haltdef }
    if (list is empty isin $1-) { haltdef | did -a ch.access 7 Access List is Empty }
  }
}

on *:DIALOG:ch.access:*:*: {
  if ($devent == init) {
    did -b $dname 3-5
    did -b $dname 7-10
    did -f $dname 2
    var %chan.var 1
    while (%chan.var <= $chan(0)) {
      did -a $dname 2 $chan(%chan.var)
      inc %chan.var
    }
  }
  if ($devent == sclick) {
    if ($did == 2) {
      did -r $dname 7
      cs access $did(2) list
      did -e $dname 7
      did -e $dname 3
      did -f $dname 3
      var %nick.var 1
      while (%nick.var <= $nick($did(2),0)) {
        did -a $dname 3 $nick($did(2),%nick.var)
        inc %nick.var
      }
    }
    if ($did == 3) { did -e $dname 4 | did -f $dname 4 }
    if ($did == 5) {
      did -r $dname 7
      cs access $did(2) add $did(3) $did(4)
      did -r $dname 4
      did -a $dname 4 Access Level
      did -b $dname 4-5
      cs access $did(2) list
    }
    if ($did == 7) { did -e $dname 8-9 }
    if ($did == 8) {
      cs access $did(2) del $gettok($did(7),1,32)
      did -r $dname 7
      did -b $dname 8-10
      cs access $did(2) list
    }
    if ($did == 10) {
      cs access $did(2) add $gettok($did(7),1,32) $did(9)
      did -r $dname 7
      did -r $dname 9
      did -a $dname 9 Access Level
      did -b $dname 8-10
      cs access $did(2) list
    }
  }
  if ($devent == edit) {
    if ($did == 3) { did -e $dname 4 }
    if ($did == 4) { did -e $dname 5 }
    if ($did == 9) { did -e $dname 10 } 
  }
}
Mirc İlk Harf Büyük Sonuna Nokta Yazı Tipi

Sohbet Girişi

   
   
Şifreniz yoksa boş bırakabilirsiniz.

Diğer Yazılar:

Yazar:

0 yorum var: “Mirc İrc Chanserv Yetki Ekleme Paneli”

Yorum Yap:

Almanya Sohbet | Bedava Sohbet | Sohbet Odaları | islami Sohbet| Mynet Sohbet | Sohbet | Chat Odaları |
CopyRight © 2018 -
Tarih : 24.11.2020
Saat : 05:53:34
itibari ile RomeO Tarafından Güncellenmiştir.

Created By RomeO

Mynet Sohbet

Sitemiz Kişisel Bir Oluşum ile Sohbet Hizmeti Vermektedir. Mynet A.ş ile hiç bir Bağımız veya ilişkimiz Bulunmamaktadır. Sitemizde 18 Yaşından Küçüklerin Bulunması Sakıncalı Olabilir . ! !